윈도우 원격포트 변경 패치파일

안녕하세요 유똥입니다.

오늘은 원격포트 변경을 자동화 하는 배치파일을 만들어 보겠습니다.

 

알려진 포트(well-known port)를 사용보다는 보안상 특정포트로 사용하는게 좋습니다.

외부에서 원격포트(RDP)로 서버에 접속 가능한 계정정보가 혹시 노출되더라도 포트 번호를 표준 포트로 사용하였을 때와 변경된 임의의 포트를 사용할 경우 보안상 훨씬 유리하기 때문입니다.

 

레지스트리(registry) 편집기를 이용하여 포트를 변경할 수 있습니다.

그러면, 레지스트리는 무엇일까?

레지스트리란 윈도우계열 시스템에서 사용하는 시스템 구성 정보를 저장한 데이터베이스를 말합니다.

프로세스종류, 주기억장치의 용량, 주변장치의 정보, 시스템 매개변수, 응용소프트웨어에서 취급하는 파일 타입과 매개변수 등을 기록한 저장소를 말합니다.

 

정리하자면, 윈도우를 이용할 때 필요한 모든 정보들이 담겨 있는 윈도우 설정 정보들이라고 생각하면 될 것 같습니다.

 

그러면 윈도우 원격포트 변경하는 배치파일 지금 만들어보겠습니다.

 

---

 윈도우 원격포트 변경 배치파일

@echo off
echo.
echo.
echo		Windows RDP Port 변경
echo		지원 OS : 윈도우 비스타, 7, 2008, 2008 R2, 2012, 2012R2, 2016, 2019
echo.
set /p port=포트 번호 입력 : 
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %port% /f
if errorlevel 1 (
	cls
	echo.
	echo.
	echo 우클릭 해서 관리자 권한으로 실행해주세요.
	pause>nul
	exit
)
netsh advfirewall firewall add rule name="원격 데스크톱 %port%" dir=in action=allow protocol=tcp localport=%port%
net stop /y TermService
net start /y TermService
echo 모든 작업이 완료되었습니다.
pause>nul
exit

 

@ECHO OFF로

내가 프로그래밍한 명령어들이 화면에 나오지 않게 할 수 있습니다.

명령어들은 출력하지 않고 ECHO 로 내가 출력하고자 했던 문자열들만 출력해줍니다.

 

SET <변수명> = <변수값> /p

- 변수를 선언할 수 있습니다.

- 직접환경변수에 할당할 문자열을 입력받을 수 있습니다.

 

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" /v fDenyTSConnections /t REG_DWORD /d 0 /f
reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server\WinStations\RDP-Tcp" /v PortNumber /t REG_DWORD /d %port% /f

ㄴ 레지스트리 추가 하는 명령어

ㄴ %port% 입력한 포트로 레지스트리 원격포트 변경

 

netsh advfirewall firewall add rule name="원격 데스톱 %port%" dir=in action=allow protocol=tcp localport=%port%

ㄴ 내가 설정한 윈도우 방화벽 추가

 

net stop /y TermService
net start /y TermService

ㄴ 터미널 서비스 재시작

 

---

 배치파일 생성

---

 실행화면

저의 경우 원격포트를 48321로 지정했습니다.

 

---

이로서, 여기까지 진행하셨다면 배치파일을 이용한, 호스트네임 변경 방법에 대해 알아봤습니다.
모두 고생하셨습니다.

도움이 되셨다면 구독과 좋아요를
궁금한 내용이 있으시면 댓글 부탁드리겠습니다!!

 

RDP_PORT.cmd

0.00MB